تابع SWITCH در DAX

یکی از کاربردهای رایج SWITCH مقایسه‌ی عبارات با مقادیر ثابت است. مثال زیر یک ستون محاسباتی از نام ماه‌ها ایجاد می‌کند:

= SWITCH (
         [Month Number Of Year],
         1, "January",
         2, "February",
         3, "March",
         4, "April",
         5, "May",
         6, "June",
         7, "July",
         8, "August",
         9, "September",
         10, "October",
         11, "November",
         12, "December",
         "Unknown month number"
        )

یکی دیگر از کاربردهای رایج SWITCH، جایگزینی چندین عبارت شرطی تو در تو است. این کار با تنظیم عبارت به TRUE انجام می‌شود، همانطور که در مثال زیر نشان داده شده است، که نقطه سفارش مجدد و سطح موجودی ایمن را در محصولات مقایسه می‌کند تا خطرات احتمالی اتمام موجودی را شناسایی کند:

= SWITCH (
        TRUE,
        [Reorder Point] > [Safety Stock Level], "Good: Safety stock level exceeded",
        [Reorder Point] = [Safety Stock Level], "Minimal: Safety stock level met",
        [Reorder Point] < [Safety Stock Level], "At risk: Safety stock level not met",
        ISBLANK ( [Reorder Point] ), "Incomplete: Reorder point not set",
        ISBLANK ( [Safety Stock Level] ), "Incomplete: Safety stock level not set",
        "Unknown"
        )

ترتیب مقادیر مهم است. در مثال زیر، نتیجه دوم هرگز بازگردانده نمی‌شود زیرا مقدار اول نسبت به مقدار دوم محدودیت کمتری دارد. نتیجه در این مثال همیشه A یا C است، اما هرگز B نیست.

= SWITCH (
         TRUE,
         Product[Standard Cost] < 100, "A",
         Product[Standard Cost] < 10, "B",
         "C"
         )

دستور زیر خطا برمی‌گرداند زیرا نوع داده در آرگومان‌های result متفاوت است. به خاطر داشته باشید که نوع داده در تمام آرگومان‌های result و else باید یکسان باشد.

= SWITCH (
        [Class],
        "L", "Large",
        "H", 0.1
        )